10 WIDTH 255
20 DIM tage(12):FOR i=1 TO 12:READ tage(i): NEXT i
80 REM geschrieben von Graman Engelbert 4020 Linz
90 REM weitere Programmteile: LAKA.BAS und KUKA.BAS, NOTIZBLOCK.BAS, DATUM.LIB, PASSWD.LIB
100 REM
110 GOSUB 640: REM escapes initialisieren
120 GOSUB 300
125 REM entrypoint
130 GOSUB 350 : REM datum eingeben
140 WIDTH 255
145 date$=tag$+"."+mon$+"."+jahr$
147 COMMON date$
150 ex=1:GOSUB 370:ex=0
153 WIDTH 255
155 COMMON date$
160 GOSUB 640:GOSUB 300
180 z=10:s=24:GOSUB 790:PRINT inv$" Kundenkartei starten     ... F1 "nrm$
181 z=12:s=24:GOSUB 790:PRINT inv$" Lagerkartei starten      ... F3 "nrm$
185 z=14:s=24:GOSUB 790:PRINT inv$" Anleitung zum Programm    ENTER "nrm$
190 z=16:s=24:GOSUB 790:PRINT inv$" Notizblock starten       ... F7 "nrm$
210 z=18:s=24:GOSUB 790:PRINT inv$" Programm beenden       ... EXIT "nrm$
220 z=20:s=24:GOSUB 790:PRINT inv$" Ihre Wahl: _"nrm$;lft$;
230 a$=INKEY$:IF a$<>CHR$(26) AND a$<>CHR$(18) AND a$<>CHR$(13) AND a$<>CHR$(17) AND a$<>CHR$(16) AND a$<>esc$ THEN 230
235 z=24:s=24:GOSUB 790:PRINT inv$" BITTE WARTEN !! "nrm$
240 IF a$=CHR$(27) THEN z=26:s=10:GOSUB 790:PRINT ecl$;inv$" Legen Sie in Laufwerk A: nun wieder die Systemdisk ein !! "nrm$:z=27:s=35:GOSUB 790:PRINT ecl$;inv$" RETURN !! "nrm$;:INPUT n$:WIDTH 89:PRINT cls$:SYSTEM
245 IF a$=CHR$(13) THEN GOTO 1000
250 IF a$=CHR$(16) THEN CHAIN"m:notbook"
260 IF a$=CHR$(26) THEN CHAIN"m:kuka",1
270 IF a$=CHR$(17) THEN CHAIN"m:laka",1
280 GOTO 220
290 END
300 PRINT cls$;
310 FOR z=1 TO 3:s=0:GOSUB 790:PRINT inv$;SPACE$(89);nrm$: NEXT z
320 z=2:s=20:GOSUB 790:PRINT inv$"HAUPTMEN] f}r LABU und KUKA Version 1.1"nrm$;
330 IF jahr$<>"" THEN z=2:s=62: GOSUB 790:PRINT inv$;date$;nrm$
340 RETURN
350 REM datumskorrektur und eingabe
370 OPEN "i",#1,"m:datum.lib"
380  INPUT #1,tag$,mon$,jahr$: CLOSE 1
390 IF ex=1 THEN RETURN
400 GOSUB 300
410 t=VAL(tag$):m=VAL(mon$):j=VAL(jahr$)
420 t=t+1:dif=j-1980
430 IF t<=tage(m)THEN 470
440 IF (t>tage(m) AND m<>2) THEN t=1:GOTO 460
450 IF (dif/4-INT(dif/4)=0 AND t=29) THEN 470 ELSE t=1
460 IF m<12 THEN m=m+1 ELSE m=1:j=j+1
470  tag$=RIGHT$(STR$(t),LEN(STR$(t))-1):mon$=RIGHT$(STR$(m),LEN(STR$(m))-1)
480  jahr$=RIGHT$(STR$(j),4)
490 PRINT
500 z=8:s=3: GOSUB 790:PRINT inv$" Bitte das heutige Datum eingeben  oder mit der ENTER-Taste den Vorschlag annehmen "nrm$
510 z=18:s=28: GOSUB 790:PRINT " TAG (tt)       :";tag$
520 z=20:s=28: GOSUB 790:PRINT " MONAT (mm)     :";mon$:
530 z=22:s=28: GOSUB 790:PRINT" JAHR (jjjj)    :";jahr$
540 z=18:s=45:GOSUB 790:INPUT "",t$:IF t$="" THEN 580 :ELSE IF VAL(t$)<32 THEN tag$=t$ ELSE 540
550 z=20:GOSUB 790:INPUT"",m$:IF m$="" THEN 580 ELSE IF VAL(m$)<13 THEN mon$=m$ ELSE 550
560 z=22:GOSUB 790:INPUT"",j$:IF j$<>"" THEN jahr$=j$
580 OPEN "o",#1,"m:datum.lib"
590 WRITE #1,tag$,mon$,jahr$
600 CLOSE 
610 GOSUB 300
620 RETURN
630 DATA 31,28,31,30,31,30,31,31,30,31,30,31
640 esc$=CHR$(27)
650 REM cls$ Schirm l|schen  hom$ Cursor home
660 hom$=esc$+"H": cls$=hom$+esc$+"E"
670 REM inv$ Invers ein    nrm$ Invers aus
680 inv$=esc$+"p":nrm$=esc$+"q"
690 REM und$ Underline ein nun$ Underline  aus
700 und$=esc$+"r":nun$=esc$+"u"
710 REM ecl$= erase cursor line  lft$=cursor left
720 ecl$=esc$+"l":lft$=esc$+"D"
730 REM rgt$= cursor right  cup$=cursor up
740 rgt$=esc$+"C":cup$=esc$+"A"
750 REM dwn$= cursor down   bel$= piepston
760 dwn$=esc$+"B":bel$=CHR$(7)
770 RETURN
780 REM position cursor
790 PRINT esc$+"Y"+CHR$(z+32)+CHR$(s+32);
800 RETURN
1000 PRINT cls$
1010 z=2:s=60:GOSUB 790:PRINT inv$" Programmbeschreibung "nrm$
1020 z=5:s=0:GOSUB 790:PRINT inv$" MEN] f}r KUKA, LAKA und NOTIZBLOCK "nrm$
1030 PRINT
1040 PRINT" In diesem Programmteil kann man diese Programmpunkte ausw{hlen oder das Programm "
1050 PRINT" mit "inv$" EXIT "nrm$" beenden. Bitte die "inv$" F-TASTEN "nrm$" verwenden ! ":GOSUB 3000
1060 z=11:s=0:GOSUB 790:PRINT inv$" KUKA-MEN] Punkte "nrm$
1070 PRINT
1080 PRINT" Als erstens kommt die Abfrage nach dem Namen und dem Passwort. Man kann diese Ein-"
1090 PRINT" gabe auch }bergehen, indem man die "inv$" ENTER-Taste "nrm$" dr}ckt. Somit sind"
1100 PRINT" bestimmte Eintragungen gesperrt (persl. DATEN). Nach Dr}cken der 1.Taste erscheint"
1101 PRINT" ein Untermen}. Nach allen diesen Punkten k|nnen SIE die Daten suchen. Als Abk}rzung"
1102 PRINT" kann nach dem 1.Buchstaben dieses "inv$" * "nrm$" Zeichen genommen werden. So werden"
1103 PRINT" z.B. alle 'A...' ausgegeben oder SIE geben nur '*' dieses Zeichen ein, dann werden"
1104 PRINT" alle Daten in den Speicher geladen. Bei jedem "inv$" DATENBLATT "nrm$" wird ein"
1105 PRINT" Untermen} eingeblendet, das sich selbst erkl{rt. Es d}rfen beim "inv$" [NDERN "nrm$
1106 PRINT" nur die "inv$" CURSOR-TASTEN "nrm$" verwendet werden. Die "inv$" RETURN/ENTER-Taste "nrm$" speichert"
1107 PRINT" den Datensatz auf den Datentr{ger."
1108 GOSUB 3000
1109 z=29:s=27:GOSUB 790:PRINT inv$" Bitte die ENTER-Taste dr}cken "nrm$
1110 a$=INKEY$:IF a$<>CHR$(13) THEN 1110
1111 PRINT cls$
1112 z=8:s=0:GOSUB 790:PRINT inv$" LAKA-Men} Punkte "nrm$
1113 PRINT
1114 PRINT" Die Bearbeitung dieses Programmteiles erfolgt genauso wie im "inv$" KUKA-Men} "nrm$" . 
1115 PRINT" Man kann st{ndig zwischen den beiden Programmen "inv$" KUKA - LAKA "nrm$" wechseln . Es wird"
1116 PRINT" immer st{ndig das aktuelle Datum angezeigt. Beim "inv$" LAKA-Men} "nrm$" gibt es ein eigenes"
1117 PRINT inv$" ZUWACHS-Konto und ein ABBUCH-Konto "nrm$" . Beim Abbuchen wird automatisch mit dem"
1118 PRINT" Drucker ein Protokoll erstellt, auf dem vermerkt wird, was nachbestellt wurde. Es ist"
1119 PRINT" auch eine "inv$" MINDEST-STAND "nrm$" ]berwachung enthalten. Sie werden nach Unterschreitung des"
1120 PRINT" Mindesstandes gefragt, wieviel Sie von diesem Produkt nachbestellen wollen.
1121 PRINT
1124 PRINT
1125 PRINT" Ich w}nsche Ihnen viel Freude mit diesem Programm "
1126 GOSUB 3000
1127 z=29:s=27:GOSUB 790:PRINT inv$" Bitte die EXIT-Taste dr}cken "nrm$
2000 a$=INKEY$:IF a$<>esc$ THEN 2000
2001 GOTO 160
3000 FOR i=1 TO 89:PRINT"_";:NEXT i:RETURN
die EXIT-Taste dr}cken "nrm$
2000 a